Errata and Updates

This page lists errata and updates for The 4D 6.5 Companion.

Bug #1 in Constants Editor in Sample Database

A bug in ConstEditor_UpdateInterface disables the add constants button when a struture without constants is open. The corrected routine is listed in the scrollable text area below, ready for copy-and-paste:

If (False)
    ` ConstEditor_UpdateInterface
    `
    ` Set enterability/visiblity of objects based on
    ` state of various arrays. This is a bunch of interface management
    ` code called in the On Clicked form event by the form method of
    ` [Dialogs];"ConstEditor"
    ` 
End if

C_LONGINT($1;$selected4DKListID_l)

C_BOOLEAN($theListIsEditable_b)
C_BOOLEAN($theListHasItems_b)
C_BOOLEAN($anItemIsSelected_b)
C_BOOLEAN($aResourceFileIsOpen_b)
C_BOOLEAN($thereIsAList_b)

$selected4DKListID_l:=$1

$thereIsAList_b:=Size of array(ConstEditor_4DKIDs_al)>0
$theListIsEditable_b:=ConstEditor_4DKListIsEditable ($selected4DKListID_l)
$theListHasItems_b:=Size of array(ConstEditor_Labels_as)>0
$anItemIsSelected_b:=ConstEditor_Labels_as>0
$aResourceFileIsOpen_b:=ConstEditor_FileIsOpen_b

` The Add buttton should be enabled if there is an open file,
  ` disabled otherwise.
If ($aResourceFileIsOpen_b)
  ENABLE BUTTON(bAddList)
Else 
  DISABLE BUTTON(bAddList)
End if

` Now configure the remainder of the interface.
Case of 
  : (Not($thereIsAList_b))
      ` There isn't a current list.
      ` Set the list area of form.
    DISABLE BUTTON(bDeleteList)
    DISABLE BUTTON(ConstEditor_Renumber_l)
    DISABLE BUTTON(ConstEditor_Rename_l)
    
      ` Set the item area of form. 
      ` Item area of form.          
    SET ENTERABLE(ConstEditor_Label_s;False)
    SET ENTERABLE(ConstEditor_Value_s;False)
    SET VISIBLE(ConstEditor_Type_s;True)  ` Show the type display.
    SET VISIBLE(ConstEditor_TypeNames_as;False)  ` Hide the type popup.
    ConstEditor_EditingTooltip_s:=""  ` Clear the tooltip.
    DISABLE BUTTON(bAddListItem)
    DISABLE BUTTON(bDeleteListItem)
    
  : ($theListIsEditable_b)
      ` Set the list area of form.
    SET ENTERABLE(ConstEditor_4DKid_l;True)
    SET ENTERABLE(ConstEditor_4DKName_s;True)
    ENABLE BUTTON(bDeleteList)
    ENABLE BUTTON(ConstEditor_Renumber_l)
    ENABLE BUTTON(ConstEditor_Rename_l)
    
      ` Set the item area of form.          
    Case of 
      : ($theListHasItems_b) & ($anItemIsSelected_b)
        GOTO AREA(ConstEditor_Label_s)
        SET ENTERABLE(ConstEditor_Label_s;True)
        SET ENTERABLE(ConstEditor_Value_s;True)
        SET VISIBLE(ConstEditor_Type_s;False)  ` Hide the type display.
        SET VISIBLE(ConstEditor_TypeNames_as;True)  ` Show the type popup.
        ConstEditor_EditingTooltip_s:=""  ` Clear the tooltip.
        ENABLE BUTTON(bAddListItem)
        ENABLE BUTTON(bDeleteListItem)
        
      : ($theListHasItems_b=False) | ($anItemIsSelected_b=False)
          ` Item area of form.          
        GOTO AREA(ConstEditor_Label_s)
        SET ENTERABLE(ConstEditor_Label_s;False)
        SET ENTERABLE(ConstEditor_Value_s;False)
        SET VISIBLE(ConstEditor_Type_s;True)  ` Show the type display.
        SET VISIBLE(ConstEditor_TypeNames_as;False)  ` Hide the type popup.
        ConstEditor_EditingTooltip_s:=""  ` Clear the tooltip.
        ENABLE BUTTON(bAddListItem)
        DISABLE BUTTON(bDeleteListItem)
        
      Else   ` This should be impossible.
        TRACE
    End case 
    
  : ($theListIsEditable_b=False)
      ` Set the list area of form.
    SET ENTERABLE(ConstEditor_4DKid_l;False)
    SET ENTERABLE(ConstEditor_4DKName_s;False)
    DISABLE BUTTON(bDeleteList)
    DISABLE BUTTON(ConstEditor_Renumber_l)
    DISABLE BUTTON(ConstEditor_Rename_l)
    
      ` Item area of form.    
    SET ENTERABLE(ConstEditor_Label_s;False)
    SET ENTERABLE(ConstEditor_Value_s;False)
    SET VISIBLE(ConstEditor_Type_s;True)  ` Show the type display.
    SET VISIBLE(ConstEditor_TypeNames_as;False)  ` Hide the type popup.
    ConstEditor_EditingTooltip_s:="You cannot modify this constant because it belongs to 4D."
    DISABLE BUTTON(bAddListItem)
    DISABLE BUTTON(bDeleteListItem)
    
  Else 
      ` This is impossible.
    TRACE
End case

` Always update the item count.
ConstEditor_UpdateItemsShownMsg

` Hide/show the display option popup.
If ($aResourceFileIsOpen_b)
  SET VISIBLE(*;"DisplayChoicePopup@";True)
Else 
  SET VISIBLE(*;"DisplayChoicePopup@";False)
End if

` End of routine.

Thanks to Achim Kruse for reporting this error. (Added March 27, 2002)

Bug #2 in Constants Editor in Sample Database

A bug in ConstEditor_Select4DKList produces a variety of display problems. The corrected routine is listed in the scrollable text area below, ready for copy-and-paste:

Thanks to Charles Stillman and John Steele for reporting this error.

Typo on page 49: The third sentence of the DataCheck Runtime paragraph uses the word “performs” instead of “performs.” The full sentence should read: “You can have one that performs a quick scan of indexes, another that scans all records in detail, a third that scans and fixes the bitmap, and a fourth that drops all indexes.”

Thanks to Douglas O. Blew for reporting this error.
Error in pseudo-code on page 292: The array index used inside the loop should be Loop Counter instead of 1 and the conjunction should be | (OR) not & (AND.) Here is how the pseudo-code should be written:; QUERY([Table];[Table]Indexed_Field=Query_array{1};*); For (Loop Counter;2;Size of array(Query_array))
QUERY([Table]; | ;[Table]Indexed_Field=Query_array{Loop Counter};*)
End for

QUERY([Table])
Thanks to Robert R. Livingston for reporting this error.
Incorrect command name listed on pages 295, 339 and 340: The 4D 6.5 command CREATE SELECTION FROM ARRAY is listed as CREATE NAMED SELECTION FROM ARRAY. The command description and sample code are correct.

Thanks to John Baughman for reporting this error.

Last updated July 19, 2000